@echo off
setlocal enabledelayedexpansion

REM === PATH SETUP ===
set PARENT_DIR=%~dp0..
set CONFIG_FILE=%PARENT_DIR%\config.json
set ENV_FILE=%PARENT_DIR%\.env

REM Check if .env file exists
if not exist "%ENV_FILE%" (
    echo [ERROR] .env file not found. Please copy .env.example to .env and configure it.
    exit /b 1
)

REM === Extract values from config.json ===
for /f "delims=" %%i in ('powershell -NoProfile -Command ^
  "Get-Content '%CONFIG_FILE%' | ConvertFrom-Json | Select-Object -ExpandProperty python_version"') do set PYTHON_VERSION=%%i
for /f "delims=" %%i in ('powershell -NoProfile -Command ^
  "Get-Content '%CONFIG_FILE%' | ConvertFrom-Json | Select-Object -ExpandProperty icon_path"') do set ICON_PATH=%%i
for /f "delims=" %%i in ('powershell -NoProfile -Command ^
  "Get-Content '%CONFIG_FILE%' | ConvertFrom-Json | Select-Object -ExpandProperty app_name"') do set APP_NAME=%%i
for /f "delims=" %%i in ('powershell -NoProfile -Command ^
  "Get-Content '%CONFIG_FILE%' | ConvertFrom-Json | Select-Object -ExpandProperty architecture"') do set ARCHITECTURE=%%i

REM === Extract python path from .env file ===
for /f "usebackq tokens=2 delims==" %%i in (`findstr "PYTHON_PATH" "%ENV_FILE%"`) do set SYSTEM_PYTHON=%%i

set VENV_PATH=%PARENT_DIR%\WINenv_%ARCHITECTURE%
set EXE_NAME=%APP_NAME%-Windows-%ARCHITECTURE%
set PYTHON_IN_VENV=%VENV_PATH%\Scripts\python.exe

REM === Verify Python existence ===
if not exist "%SYSTEM_PYTHON%" (
    echo [ERROR] Python not found at: %SYSTEM_PYTHON%
    exit /b 1
)

REM === Check if virtual environment exists ===
if not exist "%VENV_PATH%\Scripts\activate.bat" (
    echo [INFO] Virtual environment not found. Creating...
    "%SYSTEM_PYTHON%" -m venv "%VENV_PATH%"
    "%PYTHON_IN_VENV%" -m pip install --upgrade pip
    "%PYTHON_IN_VENV%" -m pip install -r "%PARENT_DIR%\requirements.txt"
) else (
    echo [INFO] Virtual environment found.
)

REM === Run PyInstaller ===
"%PYTHON_IN_VENV%" -m PyInstaller ^
  --distpath "%PARENT_DIR%\build" ^
  --workpath "%PARENT_DIR%\dist" ^
  --clean ^
  "%PARENT_DIR%\BUILD.spec"

REM === Clean build cache ===
rmdir /s /q "%PARENT_DIR%\dist"

endlocal